From c277129386f1acfe133da11f23a7d730ae48964d Mon Sep 17 00:00:00 2001
From: June McEnroe <june@causal.agency>
Date: Tue, 12 Jan 2021 22:06:56 -0500
Subject: Move hilex out of hilex directory

---
 bin/make.l | 105 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 105 insertions(+)
 create mode 100644 bin/make.l

(limited to 'bin/make.l')

diff --git a/bin/make.l b/bin/make.l
new file mode 100644
index 00000000..952c589d
--- /dev/null
+++ b/bin/make.l
@@ -0,0 +1,105 @@
+/* Copyright (C) 2020  June McEnroe <june@causal.agency>
+ *
+ * This program is free software: you can redistribute it and/or modify
+ * it under the terms of the GNU Affero General Public License as published by
+ * the Free Software Foundation, either version 3 of the License, or
+ * (at your option) any later version.
+ *
+ * This program is distributed in the hope that it will be useful,
+ * but WITHOUT ANY WARRANTY; without even the implied warranty of
+ * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+ * GNU Affero General Public License for more details.
+ *
+ * You should have received a copy of the GNU Affero General Public License
+ * along with this program.  If not, see <http://www.gnu.org/licenses/>.
+ */
+
+%option prefix="make"
+%option noyywrap
+
+%{
+#include "hilex.h"
+%}
+
+%s Assign
+%x Interp Shell
+
+ident [._[:alnum:]]+
+assign [+?:!]?=
+target [-._/?*\[\][:alnum:]]+
+operator [:!]|::
+
+%%
+	static int pop = INITIAL;
+	static int depth = 0;
+
+^"\t"+ {
+	BEGIN(pop = Shell);
+	return Normal;
+}
+<Shell>{
+	"\n" {
+		BEGIN(pop = INITIAL);
+		return Normal;
+	}
+	"\\\n" { return Normal; }
+	[^\\\n$]+|. { return Normal; }
+}
+
+[[:blank:]]+ { return Normal; }
+
+{operator} { return Operator; }
+
+"."(PHONY|PRECIOUS|SUFFIXES)/{operator}? {
+	return Keyword;
+}
+
+^{ident}/[[:blank:]]*{assign} {
+	return Identifier;
+}
+
+{assign} {
+	BEGIN(pop = Assign);
+	return Operator;
+}
+<Assign>{
+	"\n" {
+		BEGIN(pop = INITIAL);
+		return Normal;
+	}
+	"\\\n" { return String; }
+	[^\\$[:space:]]+|. { return String; }
+}
+
+^"-"?include { return Macro; }
+
+{target} { return Identifier; }
+
+"#"([^\\\n]|"\\"[^\n]|"\\\n")* { return Comment; }
+
+<*>{
+	"$"("{"|"(") {
+		depth++;
+		BEGIN(Interp);
+		return Interpolation;
+	}
+	"$". { return Interpolation; }
+}
+<Interp>{
+	"}"|")" {
+		if (!--depth) BEGIN(pop);
+		return Interpolation;
+	}
+	[^${}()]+ { return Interpolation; }
+}
+
+.|\n { return Normal; }
+
+%{
+	(void)yyunput;
+	(void)input;
+%}
+
+%%
+
+const struct Lexer LexMake = { yylex, &yyin, &yytext };
-- 
cgit 1.4.1