bin/hilex/mdoc.l


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72

/* Copyright (C) 2020  C. McEnroe <june@causal.agency>
 *
 * This program is free software: you can redistribute it and/or modify
 * it under the terms of the GNU Affero General Public License as published by
 * the Free Software Foundation, either version 3 of the License, or
 * (at your option) any later version.
 *
 * This program is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU Affero General Public License for more details.
 *
 * You should have received a copy of the GNU Affero General Public License
 * along with this program.  If not, see <http://www.gnu.org/licenses/>.
 */

%option prefix="mdoc"
%option noyywrap

%{
#include "hilex.h"
%}

%s MacroLine Heading

%%

[[:blank:]]+ { return Normal; }

^"." {
	BEGIN(MacroLine);
	return Keyword;
}

^".\\\"".* { return Comment; }

<MacroLine,Heading>{
	"\n" {
		BEGIN(0);
		return Normal;
	}

	S[hs] {
		BEGIN(Heading);
		return Keyword;
	}

	%[ABCDIJNOPQRTUV]|A[cdnopqrt]|B[cdfkloqtx]|Br[coq]|Bsx|C[dm]|D[1bcdloqtvx] |
	E[cdfklmnorsvx]|F[acdlnortx]|Hf|I[cnt]|L[bikp]|M[st]|N[dmosx]|O[copstx] |
	P[acfopq]|Q[cloq]|R[esv]|S[chmoqstxy]|T[an]|U[dx]|V[at]|X[cor] {
		return Keyword;
	}

	"\""([^""]|"\\\"")*"\"" { return String; }
}

<Heading>[^[:space:]].* { return IdentifierTag; }

"\\"(.|"("..|"["[^]]*"]") { return String; }

[^.\\""[:space:]]+ { return Normal; }

.|\n { return Normal; }

%{
	(void)yyunput;
	(void)input;
%}

%%

const struct Lexer LexMdoc = { yylex, &yyin, &yytext };