Move actual dotfiles into home directory

4 files changed, 0 insertions, 908 deletions

diff --git a/.config/nvim/autoload/pathogen.vim b/.config/nvim/autoload/pathogen.vim
deleted file mode 100644
index dbe07f00..00000000
--- a/.config/nvim/autoload/pathogen.vim
+++ /dev/null
@@ -1,289 +0,0 @@
-" pathogen.vim - path option manipulation
-" Maintainer:   Tim Pope <http://tpo.pe/>
-" Version:      2.4
-
-" Install in ~/.vim/autoload (or ~\vimfiles\autoload).
-"
-" For management of individually installed plugins in ~/.vim/bundle (or
-" ~\vimfiles\bundle), adding `execute pathogen#infect()` to the top of your
-" .vimrc is the only other setup necessary.
-"
-" The API is documented inline below.
-
-if exists("g:loaded_pathogen") || &cp
-  finish
-endif
-let g:loaded_pathogen = 1
-
-" Point of entry for basic default usage.  Give a relative path to invoke
-" pathogen#interpose() (defaults to "bundle/{}"), or an absolute path to invoke
-" pathogen#surround().  Curly braces are expanded with pathogen#expand():
-" "bundle/{}" finds all subdirectories inside "bundle" inside all directories
-" in the runtime path.
-function! pathogen#infect(...) abort
-  for path in a:0 ? filter(reverse(copy(a:000)), 'type(v:val) == type("")') : ['bundle/{}']
-    if path =~# '^\%({\=[$~\\/]\|{\=\w:[\\/]\).*[{}*]'
-      call pathogen#surround(path)
-    elseif path =~# '^\%([$~\\/]\|\w:[\\/]\)'
-      call s:warn('Change pathogen#infect('.string(path).') to pathogen#infect('.string(path.'/{}').')')
-      call pathogen#surround(path . '/{}')
-    elseif path =~# '[{}*]'
-      call pathogen#interpose(path)
-    else
-      call s:warn('Change pathogen#infect('.string(path).') to pathogen#infect('.string(path.'/{}').')')
-      call pathogen#interpose(path . '/{}')
-    endif
-  endfor
-  call pathogen#cycle_filetype()
-  if pathogen#is_disabled($MYVIMRC)
-    return 'finish'
-  endif
-  return ''
-endfunction
-
-" Split a path into a list.
-function! pathogen#split(path) abort
-  if type(a:path) == type([]) | return a:path | endif
-  if empty(a:path) | return [] | endif
-  let split = split(a:path,'\\\@<!\%(\\\\\)*\zs,')
-  return map(split,'substitute(v:val,''\\\([\\,]\)'',''\1'',"g")')
-endfunction
-
-" Convert a list to a path.
-function! pathogen#join(...) abort
-  if type(a:1) == type(1) && a:1
-    let i = 1
-    let space = ' '
-  else
-    let i = 0
-    let space = ''
-  endif
-  let path = ""
-  while i < a:0
-    if type(a:000[i]) == type([])
-      let list = a:000[i]
-      let j = 0
-      while j < len(list)
-        let escaped = substitute(list[j],'[,'.space.']\|\\[\,'.space.']\@=','\\&','g')
-        let path .= ',' . escaped
-        let j += 1
-      endwhile
-    else
-      let path .= "," . a:000[i]
-    endif
-    let i += 1
-  endwhile
-  return substitute(path,'^,','','')
-endfunction
-
-" Convert a list to a path with escaped spaces for 'path', 'tag', etc.
-function! pathogen#legacyjoin(...) abort
-  return call('pathogen#join',[1] + a:000)
-endfunction
-
-" Turn filetype detection off and back on again if it was already enabled.
-function! pathogen#cycle_filetype() abort
-  if exists('g:did_load_filetypes')
-    filetype off
-    filetype on
-  endif
-endfunction
-
-" Check if a bundle is disabled.  A bundle is considered disabled if its
-" basename or full name is included in the list g:pathogen_blacklist or the
-" comma delimited environment variable $VIMBLACKLIST.
-function! pathogen#is_disabled(path) abort
-  if a:path =~# '\~$'
-    return 1
-  endif
-  let sep = pathogen#slash()
-  let blacklist =
-        \ get(g:, 'pathogen_blacklist', get(g:, 'pathogen_disabled', [])) +
-        \ pathogen#split($VIMBLACKLIST)
-  if !empty(blacklist)
-    call map(blacklist, 'substitute(v:val, "[\\/]$", "", "")')
-  endif
-  return index(blacklist, fnamemodify(a:path, ':t')) != -1 || index(blacklist, a:path) != -1
-endfunction
-
-" Prepend the given directory to the runtime path and append its corresponding
-" after directory.  Curly braces are expanded with pathogen#expand().
-function! pathogen#surround(path) abort
-  let sep = pathogen#slash()
-  let rtp = pathogen#split(&rtp)
-  let path = fnamemodify(a:path, ':s?[\\/]\=$??')
-  let before = filter(pathogen#expand(path), '!pathogen#is_disabled(v:val)')
-  let after = filter(reverse(pathogen#expand(path, sep.'after')), '!pathogen#is_disabled(v:val[0:-7])')
-  call filter(rtp, 'index(before + after, v:val) == -1')
-  let &rtp = pathogen#join(before, rtp, after)
-  return &rtp
-endfunction
-
-" For each directory in the runtime path, add a second entry with the given
-" argument appended.  Curly braces are expanded with pathogen#expand().
-function! pathogen#interpose(name) abort
-  let sep = pathogen#slash()
-  let name = a:name
-  if has_key(s:done_bundles, name)
-    return ""
-  endif
-  let s:done_bundles[name] = 1
-  let list = []
-  for dir in pathogen#split(&rtp)
-    if dir =~# '\<after$'
-      let list += reverse(filter(pathogen#expand(dir[0:-6].name, sep.'after'), '!pathogen#is_disabled(v:val[0:-7])')) + [dir]
-    else
-      let list += [dir] + filter(pathogen#expand(dir.sep.name), '!pathogen#is_disabled(v:val)')
-    endif
-  endfor
-  let &rtp = pathogen#join(pathogen#uniq(list))
-  return 1
-endfunction
-
-let s:done_bundles = {}
-
-" Invoke :helptags on all non-$VIM doc directories in runtimepath.
-function! pathogen#helptags() abort
-  let sep = pathogen#slash()
-  for glob in pathogen#split(&rtp)
-    for dir in map(split(glob(glob), "\n"), 'v:val.sep."/doc/".sep')
-      if (dir)[0 : strlen($VIMRUNTIME)] !=# $VIMRUNTIME.sep && filewritable(dir) == 2 && !empty(split(glob(dir.'*.txt'))) && (!filereadable(dir.'tags') || filewritable(dir.'tags'))
-        silent! execute 'helptags' pathogen#fnameescape(dir)
-      endif
-    endfor
-  endfor
-endfunction
-
-command! -bar Helptags :call pathogen#helptags()
-
-" Execute the given command.  This is basically a backdoor for --remote-expr.
-function! pathogen#execute(...) abort
-  for command in a:000
-    execute command
-  endfor
-  return ''
-endfunction
-
-" Section: Unofficial
-
-function! pathogen#is_absolute(path) abort
-  return a:path =~# (has('win32') ? '^\%([\\/]\|\w:\)[\\/]\|^[~$]' : '^[/~$]')
-endfunction
-
-" Given a string, returns all possible permutations of comma delimited braced
-" alternatives of that string.  pathogen#expand('/{a,b}/{c,d}') yields
-" ['/a/c', '/a/d', '/b/c', '/b/d'].  Empty braces are treated as a wildcard
-" and globbed.  Actual globs are preserved.
-function! pathogen#expand(pattern, ...) abort
-  let after = a:0 ? a:1 : ''
-  if a:pattern =~# '{[^{}]\+}'
-    let [pre, pat, post] = split(substitute(a:pattern, '\(.\{-\}\){\([^{}]\+\)}\(.*\)', "\\1\001\\2\001\\3", ''), "\001", 1)
-    let found = map(split(pat, ',', 1), 'pre.v:val.post')
-    let results = []
-    for pattern in found
-      call extend(results, pathogen#expand(pattern))
-    endfor
-  elseif a:pattern =~# '{}'
-    let pat = matchstr(a:pattern, '^.*{}[^*]*\%($\|[\\/]\)')
-    let post = a:pattern[strlen(pat) : -1]
-    let results = map(split(glob(substitute(pat, '{}', '*', 'g')), "\n"), 'v:val.post')
-  else
-    let results = [a:pattern]
-  endif
-  let vf = pathogen#slash() . 'vimfiles'
-  call map(results, 'v:val =~# "\\*" ? v:val.after : isdirectory(v:val.vf.after) ? v:val.vf.after : isdirectory(v:val.after) ? v:val.after : ""')
-  return filter(results, '!empty(v:val)')
-endfunction
-
-" \ on Windows unless shellslash is set, / everywhere else.
-function! pathogen#slash() abort
-  return !exists("+shellslash") || &shellslash ? '/' : '\'
-endfunction
-
-function! pathogen#separator() abort
-  return pathogen#slash()
-endfunction
-
-" Convenience wrapper around glob() which returns a list.
-function! pathogen#glob(pattern) abort
-  let files = split(glob(a:pattern),"\n")
-  return map(files,'substitute(v:val,"[".pathogen#slash()."/]$","","")')
-endfunction
-
-" Like pathogen#glob(), only limit the results to directories.
-function! pathogen#glob_directories(pattern) abort
-  return filter(pathogen#glob(a:pattern),'isdirectory(v:val)')
-endfunction
-
-" Remove duplicates from a list.
-function! pathogen#uniq(list) abort
-  let i = 0
-  let seen = {}
-  while i < len(a:list)
-    if (a:list[i] ==# '' && exists('empty')) || has_key(seen,a:list[i])
-      call remove(a:list,i)
-    elseif a:list[i] ==# ''
-      let i += 1
-      let empty = 1
-    else
-      let seen[a:list[i]] = 1
-      let i += 1
-    endif
-  endwhile
-  return a:list
-endfunction
-
-" Backport of fnameescape().
-function! pathogen#fnameescape(string) abort
-  if exists('*fnameescape')
-    return fnameescape(a:string)
-  elseif a:string ==# '-'
-    return '\-'
-  else
-    return substitute(escape(a:string," \t\n*?[{`$\\%#'\"|!<"),'^[+>]','\\&','')
-  endif
-endfunction
-
-" Like findfile(), but hardcoded to use the runtimepath.
-function! pathogen#runtime_findfile(file,count) abort
-  let rtp = pathogen#join(1,pathogen#split(&rtp))
-  let file = findfile(a:file,rtp,a:count)
-  if file ==# ''
-    return ''
-  else
-    return fnamemodify(file,':p')
-  endif
-endfunction
-
-" Section: Deprecated
-
-function! s:warn(msg) abort
-  echohl WarningMsg
-  echomsg a:msg
-  echohl NONE
-endfunction
-
-" Prepend all subdirectories of path to the rtp, and append all 'after'
-" directories in those subdirectories.  Deprecated.
-function! pathogen#runtime_prepend_subdirectories(path) abort
-  call s:warn('Change pathogen#runtime_prepend_subdirectories('.string(a:path).') to pathogen#infect('.string(a:path.'/{}').')')
-  return pathogen#surround(a:path . pathogen#slash() . '{}')
-endfunction
-
-function! pathogen#incubate(...) abort
-  let name = a:0 ? a:1 : 'bundle/{}'
-  call s:warn('Change pathogen#incubate('.(a:0 ? string(a:1) : '').') to pathogen#infect('.string(name).')')
-  return pathogen#interpose(name)
-endfunction
-
-" Deprecated alias for pathogen#interpose().
-function! pathogen#runtime_append_all_bundles(...) abort
-  if a:0
-    call s:warn('Change pathogen#runtime_append_all_bundles('.string(a:1).') to pathogen#infect('.string(a:1.'/{}').')')
-  else
-    call s:warn('Change pathogen#runtime_append_all_bundles() to pathogen#infect()')
-  endif
-  return pathogen#interpose(a:0 ? a:1 . '/{}' : 'bundle/{}')
-endfunction
-
-" vim:set et sw=2 foldmethod=expr foldexpr=getline(v\:lnum)=~'^\"\ Section\:'?'>1'\:getline(v\:lnum)=~#'^fu'?'a1'\:getline(v\:lnum)=~#'^endf'?'s1'\:'=':
diff --git a/.config/nvim/colors/trivial.vim b/.config/nvim/colors/trivial.vim
deleted file mode 100644
index 55f3ced6..00000000
--- a/.config/nvim/colors/trivial.vim
+++ /dev/null
@@ -1,57 +0,0 @@
-let &t_Co = 16
-hi clear
-if exists('syntax_on')
-  syntax reset
-endif
-
-let colors_name = 'trivial'
-
-hi Normal ctermbg=NONE ctermfg=NONE
-
-hi ColorColumn ctermbg=Black
-hi EndOfBuffer ctermfg=DarkGray
-hi VertSplit cterm=NONE ctermbg=NONE ctermfg=DarkGray
-hi LineNr ctermfg=DarkGray
-hi MatchParen ctermbg=DarkGray ctermfg=White
-hi ModeMsg ctermfg=DarkGray
-hi NonText ctermfg=DarkGray
-hi Search ctermbg=Yellow ctermfg=Black
-hi StatusLine cterm=NONE ctermbg=Black ctermfg=LightGray
-hi StatusLineNC cterm=NONE ctermbg=Black ctermfg=DarkGray
-hi Visual cterm=inverse ctermbg=NONE
-
-hi Comment ctermfg=DarkBlue
-
-hi Constant ctermfg=NONE
-hi String ctermfg=DarkCyan
-hi link Character String
-
-hi Identifier cterm=NONE ctermfg=NONE
-
-hi Statement ctermfg=LightGray
-
-hi PreProc ctermfg=DarkGreen
-hi Macro ctermfg=DarkYellow
-hi link PreCondit Macro
-
-hi Type ctermfg=NONE
-hi StorageClass ctermfg=LightGray
-hi link Structure StorageClass
-hi link Typedef Structure
-
-hi Special ctermfg=LightGray
-hi SpecialComment ctermfg=LightBlue
-
-hi Underlined ctermfg=NONE
-
-hi Error ctermbg=NONE ctermfg=LightRed
-
-hi Todo ctermbg=NONE ctermfg=LightBlue
-
-hi SpecialKey ctermfg=DarkGray
-
-hi link rustModPath Identifier
-
-hi link rubyDefine Structure
-hi link rubyStringDelimiter String
-hi link rubySymbol String
diff --git a/.config/nvim/init.vim b/.config/nvim/init.vim
deleted file mode 100644
index 0e2683a3..00000000
--- a/.config/nvim/init.vim
+++ /dev/null
@@ -1,35 +0,0 @@
-set hidden
-set shortmess=atI
-set wildmode=list:longest
-set splitbelow splitright
-
-set ignorecase smartcase inccommand=nosplit
-set tabstop=4 expandtab shiftwidth=4 shiftround smartindent
-set undofile
-
-set title
-set scrolloff=1
-set number colorcolumn=80,100
-set list listchars=tab:»·,trail:·
-
-nmap <leader><leader> :nohlsearch<CR>
-command! W w
-
-colorscheme trivial
-
-autocmd BufNewFile,BufRead *.asm,*.mac setfiletype nasm
-autocmd FileType sh,zsh,ruby setlocal shiftwidth=2
-
-" Tarmak 1
-noremap n j
-noremap e k
-noremap k n
-noremap j e
-noremap N J
-noremap E K
-noremap K N
-noremap J E
-nmap <C-w>n <C-w>j
-nmap <C-w>e <C-w>k
-
-execute pathogen#infect()
diff --git a/.config/nvim/syntax/nasm.vim b/.config/nvim/syntax/nasm.vim
deleted file mode 100644
index 7eeb9abb..00000000
--- a/.config/nvim/syntax/nasm.vim
+++ /dev/null
@@ -1,527 +0,0 @@
-" Vim syntax file
-" Language:	NASM - The Netwide Assembler (v0.98)
-" Maintainer:	Andriy Sokolov	<andriy145@gmail.com>
-" Original Author:	Manuel M.H. Stol	<Manuel.Stol@allieddata.nl>
-" Former Maintainer:	Manuel M.H. Stol	<Manuel.Stol@allieddata.nl>
-" Last Change:	2012 Feb 7
-" NASM Home:	http://www.nasm.us/
-
-
-
-" Setup Syntax:
-"  Clear old syntax settings
-if version < 600
-  syn clear
-elseif exists("b:current_syntax")
-  finish
-endif
-"  Assembler syntax is case insensetive
-syn case ignore
-
-
-
-" Vim search and movement commands on identifers
-if version < 600
-  "  Comments at start of a line inside which to skip search for indentifiers
-  set comments=:;
-  "  Identifier Keyword characters (defines \k)
-  set iskeyword=@,48-57,#,$,.,?,@-@,_,~
-else
-  "  Comments at start of a line inside which to skip search for indentifiers
-  setlocal comments=:;
-  "  Identifier Keyword characters (defines \k)
-  setlocal iskeyword=@,48-57,#,$,.,?,@-@,_,~
-endif
-
-
-
-" Comments:
-syn region  nasmComment		start=";" keepend end="$" contains=@nasmGrpInComments
-syn region  nasmSpecialComment	start=";\*\*\*" keepend end="$"
-syn keyword nasmInCommentTodo	contained TODO FIXME XXX[XXXXX]
-syn cluster nasmGrpInComments	contains=nasmInCommentTodo
-syn cluster nasmGrpComments	contains=@nasmGrpInComments,nasmComment,nasmSpecialComment
-
-
-
-" Label Identifiers:
-"  in NASM: 'Everything is a Label'
-"  Definition Label = label defined by %[i]define or %[i]assign
-"  Identifier Label = label defined as first non-keyword on a line or %[i]macro
-syn match   nasmLabelError	"$\=\(\d\+\K\|[#.@]\|\$\$\k\)\k*\>"
-syn match   nasmLabel		"\<\(\h\|[?@]\)\k*\>"
-syn match   nasmLabel		"[\$\~]\(\h\|[?@]\)\k*\>"lc=1
-"  Labels starting with one or two '.' are special
-syn match   nasmLocalLabel	"\<\.\(\w\|[#$?@~]\)\k*\>"
-syn match   nasmLocalLabel	"\<\$\.\(\w\|[#$?@~]\)\k*\>"ms=s+1
-if !exists("nasm_no_warn")
-  syn match  nasmLabelWarn	"\<\~\=\$\=[_.][_.\~]*\>"
-endif
-if exists("nasm_loose_syntax")
-  syn match   nasmSpecialLabel	"\<\.\.@\k\+\>"
-  syn match   nasmSpecialLabel	"\<\$\.\.@\k\+\>"ms=s+1
-  if !exists("nasm_no_warn")
-    syn match   nasmLabelWarn	"\<\$\=\.\.@\(\d\|[#$\.~]\)\k*\>"
-  endif
-  " disallow use of nasm internal label format
-  syn match   nasmLabelError	"\<\$\=\.\.@\d\+\.\k*\>"
-else
-  syn match   nasmSpecialLabel	"\<\.\.@\(\h\|[?@]\)\k*\>"
-  syn match   nasmSpecialLabel	"\<\$\.\.@\(\h\|[?@]\)\k*\>"ms=s+1
-endif
-"  Labels can be dereferenced with '$' to destinguish them from reserved words
-syn match   nasmLabelError	"\<\$\K\k*\s*:"
-syn match   nasmLabelError	"^\s*\$\K\k*\>"
-syn match   nasmLabelError	"\<\~\s*\(\k*\s*:\|\$\=\.\k*\)"
-
-
-
-" Constants:
-syn match   nasmStringError	+["'`]+
-syn match   nasmString		+\("[^"]\{-}"\|'[^']\{-}'\|`[^"]\{-}`\)+
-syn match   nasmBinNumber	"\<[0-1_]\+b\>"
-syn match   nasmBinNumber	"\<\~[0-1_]\+b\>"lc=1
-syn match   nasmOctNumber	"\<\(\o\|_\)\+q\>"
-syn match   nasmOctNumber	"\<\~\(\o\|_\)\+q\>"lc=1
-syn match   nasmDecNumber	"\<\(\d\|_\)\+\>"
-syn match   nasmDecNumber	"\<\~\(\d\|_\)\+\>"lc=1
-syn match   nasmHexNumber	"\<\(\d\(\x\|_\)*h\|0x\(\x\|_\)\+\|\$\d\(\x\|_\)*\)\>"
-syn match   nasmHexNumber	"\<\~\(\d\(\x\|_\)*h\|0x\(\x\|_\)\+\|\$\d\(\x\|_\)*\)\>"lc=1
-syn match   nasmFltNumber	"\<\(\d\|_\)\+\.\(\d\|_\)*\(e[+-]\=\d\+\)\=\>"
-syn keyword nasmFltNumber	Inf Infinity Indefinite NaN SNaN QNaN
-syn match   nasmNumberError	"\<\~\s*\d\+\.\d*\(e[+-]\=\d\+\)\=\>"
-
-
-" Netwide Assembler Storage Directives:
-"  Storage types
-syn keyword nasmTypeError	DF EXTRN FWORD RESF TBYTE
-syn keyword nasmType		FAR NEAR SHORT
-syn keyword nasmType		BYTE WORD DWORD QWORD DQWORD HWORD DHWORD TWORD
-syn keyword nasmType		CDECL FASTCALL NONE PASCAL STDCALL
-syn keyword nasmStorage		DB DW DD DQ DDQ DT
-syn keyword nasmStorage		RESB RESW RESD RESQ RESDQ REST
-syn keyword nasmStorage		EXTERN GLOBAL COMMON
-"  Structured storage types
-syn match   nasmTypeError	"\<\(AT\|I\=\(END\)\=\(STRUCT\=\|UNION\)\|I\=END\)\>"
-syn match   nasmStructureLabel	contained "\<\(AT\|I\=\(END\)\=\(STRUCT\=\|UNION\)\|I\=END\)\>"
-"   structures cannot be nested (yet) -> use: 'keepend' and 're='
-syn cluster nasmGrpCntnStruc	contains=ALLBUT,@nasmGrpInComments,nasmMacroDef,@nasmGrpInMacros,@nasmGrpInPreCondits,nasmStructureDef,@nasmGrpInStrucs
-syn region  nasmStructureDef	transparent matchgroup=nasmStructure keepend start="^\s*STRUCT\>"hs=e-5 end="^\s*ENDSTRUCT\>"re=e-9 contains=@nasmGrpCntnStruc
-syn region  nasmStructureDef	transparent matchgroup=nasmStructure keepend start="^\s*STRUC\>"hs=e-4  end="^\s*ENDSTRUC\>"re=e-8  contains=@nasmGrpCntnStruc
-syn region  nasmStructureDef	transparent matchgroup=nasmStructure keepend start="\<ISTRUCT\=\>" end="\<IEND\(STRUCT\=\)\=\>" contains=@nasmGrpCntnStruc,nasmInStructure
-"   union types are not part of nasm (yet)
-"syn region  nasmStructureDef	transparent matchgroup=nasmStructure keepend start="^\s*UNION\>"hs=e-4 end="^\s*ENDUNION\>"re=e-8 contains=@nasmGrpCntnStruc
-"syn region  nasmStructureDef	transparent matchgroup=nasmStructure keepend start="\<IUNION\>" end="\<IEND\(UNION\)\=\>" contains=@nasmGrpCntnStruc,nasmInStructure
-syn match   nasmInStructure	contained "^\s*AT\>"hs=e-1
-syn cluster nasmGrpInStrucs	contains=nasmStructure,nasmInStructure,nasmStructureLabel
-
-
-
-" PreProcessor Instructions:
-" NAsm PreProcs start with %, but % is not a character
-syn match   nasmPreProcError	"%{\=\(%\=\k\+\|%%\+\k*\|[+-]\=\d\+\)}\="
-if exists("nasm_loose_syntax")
-  syn cluster nasmGrpNxtCtx	contains=nasmStructureLabel,nasmLabel,nasmLocalLabel,nasmSpecialLabel,nasmLabelError,nasmPreProcError
-else
-  syn cluster nasmGrpNxtCtx	contains=nasmStructureLabel,nasmLabel,nasmLabelError,nasmPreProcError
-endif
-
-"  Multi-line macro
-syn cluster nasmGrpCntnMacro	contains=ALLBUT,@nasmGrpInComments,nasmStructureDef,@nasmGrpInStrucs,nasmMacroDef,@nasmGrpPreCondits,nasmMemReference,nasmInMacPreCondit,nasmInMacStrucDef
-syn region  nasmMacroDef	matchgroup=nasmMacro keepend start="^\s*%macro\>"hs=e-5 start="^\s*%imacro\>"hs=e-6 end="^\s*%endmacro\>"re=e-9 contains=@nasmGrpCntnMacro,nasmInMacStrucDef
-if exists("nasm_loose_syntax")
-  syn match  nasmInMacLabel	contained "%\(%\k\+\>\|{%\k\+}\)"
-  syn match  nasmInMacLabel	contained "%\($\+\(\w\|[#\.?@~]\)\k*\>\|{$\+\(\w\|[#\.?@~]\)\k*}\)"
-  syn match  nasmInMacPreProc	contained "^\s*%\(push\|repl\)\>"hs=e-4 skipwhite nextgroup=nasmStructureLabel,nasmLabel,nasmInMacParam,nasmLocalLabel,nasmSpecialLabel,nasmLabelError,nasmPreProcError
-  if !exists("nasm_no_warn")
-    syn match nasmInMacLblWarn	contained "%\(%[$\.]\k*\>\|{%[$\.]\k*}\)"
-    syn match nasmInMacLblWarn	contained "%\($\+\(\d\|[#\.@~]\)\k*\|{\$\+\(\d\|[#\.@~]\)\k*}\)"
-    hi link nasmInMacCatLabel	nasmInMacLblWarn
-  else
-    hi link nasmInMacCatLabel	nasmInMacLabel
-  endif
-else
-  syn match  nasmInMacLabel	contained "%\(%\(\w\|[#?@~]\)\k*\>\|{%\(\w\|[#?@~]\)\k*}\)"
-  syn match  nasmInMacLabel	contained "%\($\+\(\h\|[?@]\)\k*\>\|{$\+\(\h\|[?@]\)\k*}\)"
-  hi link nasmInMacCatLabel	nasmLabelError
-endif
-syn match   nasmInMacCatLabel	contained "\d\K\k*"lc=1
-syn match   nasmInMacLabel	contained "\d}\k\+"lc=2
-if !exists("nasm_no_warn")
-  syn match  nasmInMacLblWarn	contained "%\(\($\+\|%\)[_~][._~]*\>\|{\($\+\|%\)[_~][._~]*}\)"
-endif
-syn match   nasmInMacPreProc	contained "^\s*%pop\>"hs=e-3
-syn match   nasmInMacPreProc	contained "^\s*%\(push\|repl\)\>"hs=e-4 skipwhite nextgroup=@nasmGrpNxtCtx
-"   structures cannot be nested (yet) -> use: 'keepend' and 're='
-syn region  nasmInMacStrucDef	contained transparent matchgroup=nasmStructure keepend start="^\s*STRUCT\>"hs=e-5 end="^\s*ENDSTRUCT\>"re=e-9 contains=@nasmGrpCntnMacro
-syn region  nasmInMacStrucDef	contained transparent matchgroup=nasmStructure keepend start="^\s*STRUC\>"hs=e-4  end="^\s*ENDSTRUC\>"re=e-8  contains=@nasmGrpCntnMacro
-syn region  nasmInMacStrucDef	contained transparent matchgroup=nasmStructure keepend start="\<ISTRUCT\=\>" end="\<IEND\(STRUCT\=\)\=\>" contains=@nasmGrpCntnMacro,nasmInStructure
-"   union types are not part of nasm (yet)
-"syn region  nasmInMacStrucDef	contained transparent matchgroup=nasmStructure keepend start="^\s*UNION\>"hs=e-4 end="^\s*ENDUNION\>"re=e-8 contains=@nasmGrpCntnMacro
-"syn region  nasmInMacStrucDef	contained transparent matchgroup=nasmStructure keepend start="\<IUNION\>" end="\<IEND\(UNION\)\=\>" contains=@nasmGrpCntnMacro,nasmInStructure
-syn region  nasmInMacPreConDef	contained transparent matchgroup=nasmInMacPreCondit start="^\s*%ifnidni\>"hs=e-7 start="^\s*%if\(idni\|n\(ctx\|def\|idn\|num\|str\)\)\>"hs=e-6 start="^\s*%if\(ctx\|def\|idn\|nid\|num\|str\)\>"hs=e-5 start="^\s*%ifid\>"hs=e-4 start="^\s*%if\>"hs=e-2 end="%endif\>" contains=@nasmGrpCntnMacro,nasmInMacPreCondit,nasmInPreCondit
-" Todo: allow STRUC/ISTRUC to be used inside preprocessor conditional block
-syn match   nasmInMacPreCondit	contained transparent "ctx\s"lc=3 skipwhite nextgroup=@nasmGrpNxtCtx
-syn match   nasmInMacPreCondit	contained "^\s*%elifctx\>"hs=e-7 skipwhite nextgroup=@nasmGrpNxtCtx
-syn match   nasmInMacPreCondit	contained "^\s*%elifnctx\>"hs=e-8 skipwhite nextgroup=@nasmGrpNxtCtx
-syn match   nasmInMacParamNum	contained "\<\d\+\.list\>"me=e-5
-syn match   nasmInMacParamNum	contained "\<\d\+\.nolist\>"me=e-7
-syn match   nasmInMacDirective	contained "\.\(no\)\=list\>"
-syn match   nasmInMacMacro	contained transparent "macro\s"lc=5 skipwhite nextgroup=nasmStructureLabel
-syn match   nasmInMacMacro	contained "^\s*%rotate\>"hs=e-6
-syn match   nasmInMacParam	contained "%\([+-]\=\d\+\|{[+-]\=\d\+}\)"
-"   nasm conditional macro operands/arguments
-"   Todo: check feasebility; add too nasmGrpInMacros, etc.
-"syn match   nasmInMacCond	contained "\<\(N\=\([ABGL]E\=\|[CEOSZ]\)\|P[EO]\=\)\>"
-syn cluster nasmGrpInMacros	contains=nasmMacro,nasmInMacMacro,nasmInMacParam,nasmInMacParamNum,nasmInMacDirective,nasmInMacLabel,nasmInMacLblWarn,nasmInMacMemRef,nasmInMacPreConDef,nasmInMacPreCondit,nasmInMacPreProc,nasmInMacStrucDef
-
-"   Context pre-procs that are better used inside a macro
-if exists("nasm_ctx_outside_macro")
-  syn region nasmPreConditDef	transparent matchgroup=nasmCtxPreCondit start="^\s*%ifnctx\>"hs=e-6 start="^\s*%ifctx\>"hs=e-5 end="%endif\>" contains=@nasmGrpCntnPreCon
-  syn match  nasmCtxPreProc	"^\s*%pop\>"hs=e-3
-  if exists("nasm_loose_syntax")
-    syn match   nasmCtxLocLabel	"%$\+\(\w\|[#.?@~]\)\k*\>"
-  else
-    syn match   nasmCtxLocLabel	"%$\+\(\h\|[?@]\)\k*\>"
-  endif
-  syn match nasmCtxPreProc	"^\s*%\(push\|repl\)\>"hs=e-4 skipwhite nextgroup=@nasmGrpNxtCtx
-  syn match nasmCtxPreCondit	contained transparent "ctx\s"lc=3 skipwhite nextgroup=@nasmGrpNxtCtx
-  syn match nasmCtxPreCondit	contained "^\s*%elifctx\>"hs=e-7 skipwhite nextgroup=@nasmGrpNxtCtx
-  syn match nasmCtxPreCondit	contained "^\s*%elifnctx\>"hs=e-8 skipwhite nextgroup=@nasmGrpNxtCtx
-  if exists("nasm_no_warn")
-    hi link nasmCtxPreCondit	nasmPreCondit
-    hi link nasmCtxPreProc	nasmPreProc
-    hi link nasmCtxLocLabel	nasmLocalLabel
-  else
-    hi link nasmCtxPreCondit	nasmPreProcWarn
-    hi link nasmCtxPreProc	nasmPreProcWarn
-    hi link nasmCtxLocLabel	nasmLabelWarn
-  endif
-endif
-
-"  Conditional assembly
-syn cluster nasmGrpCntnPreCon	contains=ALLBUT,@nasmGrpInComments,@nasmGrpInMacros,@nasmGrpInStrucs
-syn region  nasmPreConditDef	transparent matchgroup=nasmPreCondit start="^\s*%ifnidni\>"hs=e-7 start="^\s*%if\(idni\|n\(def\|idn\|num\|str\)\)\>"hs=e-6 start="^\s*%if\(def\|idn\|nid\|num\|str\)\>"hs=e-5 start="^\s*%ifid\>"hs=e-4 start="^\s*%if\>"hs=e-2 end="%endif\>" contains=@nasmGrpCntnPreCon
-syn match   nasmInPreCondit	contained "^\s*%el\(if\|se\)\>"hs=e-4
-syn match   nasmInPreCondit	contained "^\s*%elifid\>"hs=e-6
-syn match   nasmInPreCondit	contained "^\s*%elif\(def\|idn\|nid\|num\|str\)\>"hs=e-7
-syn match   nasmInPreCondit	contained "^\s*%elif\(n\(def\|idn\|num\|str\)\|idni\)\>"hs=e-8
-syn match   nasmInPreCondit	contained "^\s*%elifnidni\>"hs=e-9
-syn cluster nasmGrpInPreCondits	contains=nasmPreCondit,nasmInPreCondit,nasmCtxPreCondit
-syn cluster nasmGrpPreCondits	contains=nasmPreConditDef,@nasmGrpInPreCondits,nasmCtxPreProc,nasmCtxLocLabel
-
-"  Other pre-processor statements
-syn match   nasmPreProc		"^\s*%\(rep\|use\)\>"hs=e-3
-syn match   nasmPreProc		"^\s*%line\>"hs=e-4
-syn match   nasmPreProc		"^\s*%\(clear\|error\|fatal\)\>"hs=e-5
-syn match   nasmPreProc		"^\s*%\(endrep\|strlen\|substr\)\>"hs=e-6
-syn match   nasmPreProc		"^\s*%\(exitrep\|warning\)\>"hs=e-7
-syn match   nasmDefine		"^\s*%undef\>"hs=e-5
-syn match   nasmDefine		"^\s*%\(assign\|define\)\>"hs=e-6
-syn match   nasmDefine		"^\s*%i\(assign\|define\)\>"hs=e-7
-syn match   nasmDefine		"^\s*%unmacro\>"hs=e-7
-syn match   nasmInclude		"^\s*%include\>"hs=e-7
-" Todo: Treat the line tail after %fatal, %error, %warning as text
-
-"  Multiple pre-processor instructions on single line detection (obsolete)
-"syn match   nasmPreProcError	+^\s*\([^\t "%';][^"%';]*\|[^\t "';][^"%';]\+\)%\a\+\>+
-syn cluster nasmGrpPreProcs	contains=nasmMacroDef,@nasmGrpInMacros,@nasmGrpPreCondits,nasmPreProc,nasmDefine,nasmInclude,nasmPreProcWarn,nasmPreProcError
-
-
-
-" Register Identifiers:
-"  Register operands:
-syn match   nasmGen08Register	"\<[A-D][HL]\>"
-syn match   nasmGen16Register	"\<\([A-D]X\|[DS]I\|[BS]P\)\>"
-syn match   nasmGen32Register	"\<E\([A-D]X\|[DS]I\|[BS]P\)\>"
-syn match   nasmGen64Register	"\<R\([A-D]X\|[DS]I\|[BS]P\|[89]\|1[0-5]\|[89][WD]\|1[0-5][WD]\)\>"
-syn match   nasmSegRegister	"\<[C-GS]S\>"
-syn match   nasmSpcRegister	"\<E\=IP\>"
-syn match   nasmFpuRegister	"\<ST\o\>"
-syn match   nasmMmxRegister	"\<MM\o\>"
-syn match   nasmSseRegister	"\<XMM\o\>"
-syn match   nasmCtrlRegister	"\<CR\o\>"
-syn match   nasmDebugRegister	"\<DR\o\>"
-syn match   nasmTestRegister	"\<TR\o\>"
-syn match   nasmRegisterError	"\<\(CR[15-9]\|DR[4-58-9]\|TR[0-28-9]\)\>"
-syn match   nasmRegisterError	"\<X\=MM[8-9]\>"
-syn match   nasmRegisterError	"\<ST\((\d)\|[8-9]\>\)"
-syn match   nasmRegisterError	"\<E\([A-D][HL]\|[C-GS]S\)\>"
-"  Memory reference operand (address):
-syn match   nasmMemRefError	"[[\]]"
-syn cluster nasmGrpCntnMemRef	contains=ALLBUT,@nasmGrpComments,@nasmGrpPreProcs,@nasmGrpInStrucs,nasmMemReference,nasmMemRefError
-syn match   nasmInMacMemRef	contained "\[[^;[\]]\{-}\]" contains=@nasmGrpCntnMemRef,nasmPreProcError,nasmInMacLabel,nasmInMacLblWarn,nasmInMacParam
-syn match   nasmMemReference	"\[[^;[\]]\{-}\]" contains=@nasmGrpCntnMemRef,nasmPreProcError,nasmCtxLocLabel
-
-
-
-" Netwide Assembler Directives:
-"  Compilation constants
-syn keyword nasmConstant	__BITS__ __DATE__ __FILE__ __FORMAT__ __LINE__
-syn keyword nasmConstant	__NASM_MAJOR__ __NASM_MINOR__ __NASM_VERSION__
-syn keyword nasmConstant	__TIME__
-"  Instruction modifiers
-syn match   nasmInstructnError	"\<TO\>"
-syn match   nasmInstrModifier	"\(^\|:\)\s*[C-GS]S\>"ms=e-1
-syn keyword nasmInstrModifier	A16 A32 O16 O32
-syn match   nasmInstrModifier	"\<F\(ADD\|MUL\|\(DIV\|SUB\)R\=\)\s\+TO\>"lc=5,ms=e-1
-"   the 'to' keyword is not allowed for fpu-pop instructions (yet)
-"syn match   nasmInstrModifier	"\<F\(ADD\|MUL\|\(DIV\|SUB\)R\=\)P\s\+TO\>"lc=6,ms=e-1
-"  NAsm directives
-syn keyword nasmRepeat		TIMES
-syn keyword nasmDirective	ALIGN[B] INCBIN EQU NOSPLIT SPLIT
-syn keyword nasmDirective	ABSOLUTE BITS SECTION SEGMENT
-syn keyword nasmDirective	ENDSECTION ENDSEGMENT
-syn keyword nasmDirective	__SECT__
-"  Macro created standard directives: (requires %include)
-syn case match
-syn keyword nasmStdDirective	ENDPROC EPILOGUE LOCALS PROC PROLOGUE USES
-syn keyword nasmStdDirective	ENDIF ELSE ELIF ELSIF IF
-"syn keyword nasmStdDirective	BREAK CASE DEFAULT ENDSWITCH SWITCH
-"syn keyword nasmStdDirective	CASE OF ENDCASE
-syn keyword nasmStdDirective	DO ENDFOR ENDWHILE FOR REPEAT UNTIL WHILE EXIT
-syn case ignore
-"  Format specific directives: (all formats)
-"  (excluded: extension directives to section, global, common and extern)
-syn keyword nasmFmtDirective	ORG
-syn keyword nasmFmtDirective	EXPORT IMPORT GROUP UPPERCASE SEG WRT
-syn keyword nasmFmtDirective	LIBRARY
-syn case match
-syn keyword nasmFmtDirective	_GLOBAL_OFFSET_TABLE_ __GLOBAL_OFFSET_TABLE_
-syn keyword nasmFmtDirective	..start ..got ..gotoff ..gotpc ..plt ..sym
-syn case ignore
-
-
-
-" Standard Instructions:
-syn match   nasmInstructnError	"\<\(F\=CMOV\|SET\)N\=\a\{0,2}\>"
-syn keyword nasmInstructnError	CMPS MOVS LCS LODS STOS XLAT
-syn match   nasmStdInstruction	"\<MOV\>"
-syn match   nasmInstructnError	"\<MOV\s[^,;[]*\<CS\>\s*[^:]"he=e-1
-syn match   nasmStdInstruction	"\<\(CMOV\|J\|SET\)\(N\=\([ABGL]E\=\|[CEOSZ]\)\|P[EO]\=\)\>"
-syn match   nasmStdInstruction	"\<POP\>"
-syn keyword nasmStdInstruction	AAA AAD AAM AAS ADC ADD AND
-syn keyword nasmStdInstruction	BOUND BSF BSR BSWAP BT[C] BTR BTS
-syn keyword nasmStdInstruction	CALL CBW CDQ CLC CLD CMC CMP CMPSB CMPSD CMPSW CMPSQ
-syn keyword nasmStdInstruction	CMPXCHG CMPXCHG8B CPUID CWD[E] CQO
-syn keyword nasmStdInstruction	DAA DAS DEC DIV ENTER
-syn keyword nasmStdInstruction	IDIV IMUL INC INT[O] IRET[D] IRETW IRETQ
-syn keyword nasmStdInstruction	JCXZ JECXZ JMP
-syn keyword nasmStdInstruction	LAHF LDS LEA LEAVE LES LFS LGS LODSB LODSD LODSQ
-syn keyword nasmStdInstruction	LODSW LOOP[E] LOOPNE LOOPNZ LOOPZ LSS
-syn keyword nasmStdInstruction	MOVSB MOVSD MOVSW MOVSX MOVSQ MOVZX MUL NEG NOP NOT
-syn keyword nasmStdInstruction	OR POPA[D] POPAW POPF[D] POPFW POPFQ
-syn keyword nasmStdInstruction	PUSH[AD] PUSHAW PUSHF[D] PUSHFW PUSHFQ
-syn keyword nasmStdInstruction	RCL RCR RETF RET[N] ROL ROR
-syn keyword nasmStdInstruction	SAHF SAL SAR SBB SCASB SCASD SCASW
-syn keyword nasmStdInstruction	SHL[D] SHR[D] STC STD STOSB STOSD STOSW STOSQ SUB
-syn keyword nasmStdInstruction	TEST XADD XCHG XLATB XOR
-syn keyword nasmStdInstruction	LFENCE MFENCE SFENCE
-
-
-" System Instructions: (usually privileged)
-"  Verification of pointer parameters
-syn keyword nasmSysInstruction	ARPL LAR LSL VERR VERW
-"  Addressing descriptor tables
-syn keyword nasmSysInstruction	LLDT SLDT LGDT SGDT
-"  Multitasking
-syn keyword nasmSysInstruction	LTR STR
-"  Coprocessing and Multiprocessing (requires fpu and multiple cpu's resp.)
-syn keyword nasmSysInstruction	CLTS LOCK WAIT
-"  Input and Output
-syn keyword nasmInstructnError	INS OUTS
-syn keyword nasmSysInstruction	IN INSB INSW INSD OUT OUTSB OUTSB OUTSW OUTSD
-"  Interrupt control
-syn keyword nasmSysInstruction	CLI STI LIDT SIDT
-"  System control
-syn match   nasmSysInstruction	"\<MOV\s[^;]\{-}\<CR\o\>"me=s+3
-syn keyword nasmSysInstruction	HLT INVD LMSW
-syn keyword nasmSseInstruction	PREFETCHT0 PREFETCHT1 PREFETCHT2 PREFETCHNTA
-syn keyword nasmSseInstruction	RSM SFENCE SMSW SYSENTER SYSEXIT UD2 WBINVD
-"  TLB (Translation Lookahead Buffer) testing
-syn match   nasmSysInstruction	"\<MOV\s[^;]\{-}\<TR\o\>"me=s+3
-syn keyword nasmSysInstruction	INVLPG
-
-" Debugging Instructions: (privileged)
-syn match   nasmDbgInstruction	"\<MOV\s[^;]\{-}\<DR\o\>"me=s+3
-syn keyword nasmDbgInstruction	INT1 INT3 RDMSR RDTSC RDPMC WRMSR
-
-
-" Floating Point Instructions: (requires FPU)
-syn match   nasmFpuInstruction	"\<FCMOVN\=\([AB]E\=\|[CEPUZ]\)\>"
-syn keyword nasmFpuInstruction	F2XM1 FABS FADD[P] FBLD FBSTP
-syn keyword nasmFpuInstruction	FCHS FCLEX FCOM[IP] FCOMP[P] FCOS
-syn keyword nasmFpuInstruction	FDECSTP FDISI FDIV[P] FDIVR[P] FENI FFREE
-syn keyword nasmFpuInstruction	FIADD FICOM[P] FIDIV[R] FILD
-syn keyword nasmFpuInstruction	FIMUL FINCSTP FINIT FIST[P] FISUB[R]
-syn keyword nasmFpuInstruction	FLD[1] FLDCW FLDENV FLDL2E FLDL2T FLDLG2
-syn keyword nasmFpuInstruction	FLDLN2 FLDPI FLDZ FMUL[P]
-syn keyword nasmFpuInstruction	FNCLEX FNDISI FNENI FNINIT FNOP FNSAVE
-syn keyword nasmFpuInstruction	FNSTCW FNSTENV FNSTSW FNSTSW
-syn keyword nasmFpuInstruction	FPATAN FPREM[1] FPTAN FRNDINT FRSTOR
-syn keyword nasmFpuInstruction	FSAVE FSCALE FSETPM FSIN FSINCOS FSQRT
-syn keyword nasmFpuInstruction	FSTCW FSTENV FST[P] FSTSW FSUB[P] FSUBR[P]
-syn keyword nasmFpuInstruction	FTST FUCOM[IP] FUCOMP[P]
-syn keyword nasmFpuInstruction	FXAM FXCH FXTRACT FYL2X FYL2XP1
-
-
-" Multi Media Xtension Packed Instructions: (requires MMX unit)
-"  Standard MMX instructions: (requires MMX1 unit)
-syn match   nasmInstructnError	"\<P\(ADD\|SUB\)U\=S\=[DQ]\=\>"
-syn match   nasmInstructnError	"\<PCMP\a\{0,2}[BDWQ]\=\>"
-syn keyword nasmMmxInstruction	EMMS MOVD MOVQ
-syn keyword nasmMmxInstruction	PACKSSDW PACKSSWB PACKUSWB PADDB PADDD PADDW
-syn keyword nasmMmxInstruction	PADDSB PADDSW PADDUSB PADDUSW PAND[N]
-syn keyword nasmMmxInstruction	PCMPEQB PCMPEQD PCMPEQW PCMPGTB PCMPGTD PCMPGTW
-syn keyword nasmMmxInstruction	PMACHRIW PMADDWD PMULHW PMULLW POR
-syn keyword nasmMmxInstruction	PSLLD PSLLQ PSLLW PSRAD PSRAW PSRLD PSRLQ PSRLW
-syn keyword nasmMmxInstruction	PSUBB PSUBD PSUBW PSUBSB PSUBSW PSUBUSB PSUBUSW
-syn keyword nasmMmxInstruction	PUNPCKHBW PUNPCKHDQ PUNPCKHWD
-syn keyword nasmMmxInstruction	PUNPCKLBW PUNPCKLDQ PUNPCKLWD PXOR
-"  Extended MMX instructions: (requires MMX2/SSE unit)
-syn keyword nasmMmxInstruction	MASKMOVQ MOVNTQ
-syn keyword nasmMmxInstruction	PAVGB PAVGW PEXTRW PINSRW PMAXSW PMAXUB
-syn keyword nasmMmxInstruction	PMINSW PMINUB PMOVMSKB PMULHUW PSADBW PSHUFW
-
-
-" Streaming SIMD Extension Packed Instructions: (requires SSE unit)
-syn match   nasmInstructnError	"\<CMP\a\{1,5}[PS]S\>"
-syn match   nasmSseInstruction	"\<CMP\(N\=\(EQ\|L[ET]\)\|\(UN\)\=ORD\)\=[PS]S\>"
-syn keyword nasmSseInstruction	ADDPS ADDSS ANDNPS ANDPS
-syn keyword nasmSseInstruction	COMISS CVTPI2PS CVTPS2PI
-syn keyword nasmSseInstruction	CVTSI2SS CVTSS2SI CVTTPS2PI CVTTSS2SI
-syn keyword nasmSseInstruction	DIVPS DIVSS FXRSTOR FXSAVE LDMXCSR
-syn keyword nasmSseInstruction	MAXPS MAXSS MINPS MINSS MOVAPS MOVHLPS MOVHPS
-syn keyword nasmSseInstruction	MOVLHPS MOVLPS MOVMSKPS MOVNTPS MOVSS MOVUPS
-syn keyword nasmSseInstruction	MULPS MULSS
-syn keyword nasmSseInstruction	ORPS RCPPS RCPSS RSQRTPS RSQRTSS
-syn keyword nasmSseInstruction	SHUFPS SQRTPS SQRTSS STMXCSR SUBPS SUBSS
-syn keyword nasmSseInstruction	UCOMISS UNPCKHPS UNPCKLPS XORPS
-
-
-" Three Dimensional Now Packed Instructions: (requires 3DNow! unit)
-syn keyword nasmNowInstruction	FEMMS PAVGUSB PF2ID PFACC PFADD PFCMPEQ PFCMPGE
-syn keyword nasmNowInstruction	PFCMPGT PFMAX PFMIN PFMUL PFRCP PFRCPIT1
-syn keyword nasmNowInstruction	PFRCPIT2 PFRSQIT1 PFRSQRT PFSUB[R] PI2FD
-syn keyword nasmNowInstruction	PMULHRWA PREFETCH[W]
-
-
-" Vendor Specific Instructions:
-"  Cyrix instructions (requires Cyrix processor)
-syn keyword nasmCrxInstruction	PADDSIW PAVEB PDISTIB PMAGW PMULHRW[C] PMULHRIW
-syn keyword nasmCrxInstruction	PMVGEZB PMVLZB PMVNZB PMVZB PSUBSIW
-syn keyword nasmCrxInstruction	RDSHR RSDC RSLDT SMINT SMINTOLD SVDC SVLDT SVTS
-syn keyword nasmCrxInstruction	WRSHR
-"  AMD instructions (requires AMD processor)
-syn keyword nasmAmdInstruction	SYSCALL SYSRET
-
-
-" Undocumented Instructions:
-syn match   nasmUndInstruction	"\<POP\s[^;]*\<CS\>"me=s+3
-syn keyword nasmUndInstruction	CMPXCHG486 IBTS ICEBP INT01 INT03 LOADALL
-syn keyword nasmUndInstruction	LOADALL286 LOADALL386 SALC SMI UD1 UMOV XBTS
-
-
-
-" Synchronize Syntax:
-syn sync clear
-syn sync minlines=50		"for multiple region nesting
-syn sync match  nasmSync	grouphere nasmMacroDef "^\s*%i\=macro\>"me=s-1
-syn sync match	nasmSync	grouphere NONE	       "^\s*%endmacro\>"
-
-
-" Define the default highlighting.
-" For version 5.7 and earlier: only when not done already
-" For version 5.8 and later  : only when an item doesn't have highlighting yet
-if version >= 508 || !exists("did_nasm_syntax_inits")
-  if version < 508
-    let did_nasm_syntax_inits = 1
-    command -nargs=+ HiLink hi link <args>
-  else
-    command -nargs=+ HiLink hi def link <args>
-  endif
-
-  " Sub Links:
-  HiLink nasmInMacDirective	nasmDirective
-  HiLink nasmInMacLabel		nasmLocalLabel
-  HiLink nasmInMacLblWarn	nasmLabelWarn
-  HiLink nasmInMacMacro		nasmMacro
-  HiLink nasmInMacParam		nasmMacro
-  HiLink nasmInMacParamNum	nasmDecNumber
-  HiLink nasmInMacPreCondit	nasmPreCondit
-  HiLink nasmInMacPreProc	nasmPreProc
-  HiLink nasmInPreCondit	nasmPreCondit
-  HiLink nasmInStructure	nasmStructure
-  HiLink nasmStructureLabel	nasmStructure
-
-  " Comment Group:
-  HiLink nasmComment		Comment
-  HiLink nasmSpecialComment	SpecialComment
-  HiLink nasmInCommentTodo	Todo
-
-  " Constant Group:
-  HiLink nasmString		String
-  HiLink nasmStringError	Error
-  HiLink nasmBinNumber		Number
-  HiLink nasmOctNumber		Number
-  HiLink nasmDecNumber		Number
-  HiLink nasmHexNumber		Number
-  HiLink nasmFltNumber		Float
-  HiLink nasmNumberError	Error
-
-  " Identifier Group:
-  HiLink nasmLabel		Identifier
-  HiLink nasmLocalLabel		Identifier
-  HiLink nasmSpecialLabel	Special
-  HiLink nasmLabelError		Error
-  HiLink nasmLabelWarn		Todo
-
-  " PreProc Group:
-  HiLink nasmPreProc		PreProc
-  HiLink nasmDefine		Define
-  HiLink nasmInclude		Include
-  HiLink nasmMacro		Macro
-  HiLink nasmPreCondit		PreCondit
-  HiLink nasmPreProcError	Error
-  HiLink nasmPreProcWarn	Todo
-
-  " Type Group:
-  HiLink nasmType		Type
-  HiLink nasmStorage		StorageClass
-  HiLink nasmStructure		Structure
-  HiLink nasmTypeError		Error
-
-  " Directive Group:
-  HiLink nasmConstant		Constant
-  HiLink nasmInstrModifier	Operator
-  HiLink nasmRepeat		Repeat
-  HiLink nasmDirective		Keyword
-  HiLink nasmStdDirective	Operator
-  HiLink nasmFmtDirective	Keyword
-
-  " Register Group:
-  HiLink nasmCtrlRegister	Special
-  HiLink nasmDebugRegister	Debug
-  HiLink nasmTestRegister	Special
-  HiLink nasmRegisterError	Error
-  HiLink nasmMemRefError	Error
-
-  " Instruction Group:
-  HiLink nasmStdInstruction	Statement
-  HiLink nasmSysInstruction	Statement
-  HiLink nasmDbgInstruction	Debug
-  HiLink nasmFpuInstruction	Statement
-  HiLink nasmMmxInstruction	Statement
-  HiLink nasmSseInstruction	Statement
-  HiLink nasmNowInstruction	Statement
-  HiLink nasmAmdInstruction	Special
-  HiLink nasmCrxInstruction	Special
-  HiLink nasmUndInstruction	Todo
-  HiLink nasmInstructnError	Error
-
-  delcommand HiLink
-endif
-
-let b:current_syntax = "nasm"
-
-" vim:ts=8 sw=4