1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
|
/* Copyright (C) 2021 C. McEnroe <june@causal.agency>
*
* This program is free software: you can redistribute it and/or modify
* it under the terms of the GNU Affero General Public License as published by
* the Free Software Foundation, either version 3 of the License, or
* (at your option) any later version.
*
* This program is distributed in the hope that it will be useful,
* but WITHOUT ANY WARRANTY; without even the implied warranty of
* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
* GNU Affero General Public License for more details.
*
* You should have received a copy of the GNU Affero General Public License
* along with this program. If not, see <http://www.gnu.org/licenses/>.
*/
%option prefix="sh"
%option noyywrap
%{
#include <assert.h>
#include <stdbool.h>
#include <string.h>
#include "hilex.h"
enum { Cap = 64 };
static int len = 1;
static int stack[Cap];
static int push(int val) {
if (len < Cap) stack[len++] = val;
return val;
}
static int pop(void) {
if (len > 1) len--;
return stack[len-1];
}
%}
%s Param Command Arith Backtick
%x DQuote HereDocDel HereDoc HereDocLit
word [[:alnum:]_.-]+
param [^:=?+%#{}-]+
reserved [!{}]|else|do|elif|for|done|fi|then|until|while|if|case|esac
%%
static bool first;
static char *delimiter;
[[:blank:]]+ { return Normal; }
"\\". { return Escape; }
<INITIAL,DQuote,HereDoc,Param,Command,Arith>{
"$"[*@#?$!0-9-] |
"$"[_[:alpha:][_[:alnum:]]* |
"${"[#]?{param}"}" {
return Subst;
}
"${"{param} {
BEGIN(push(Param));
return Subst;
}
"$(" {
BEGIN(push(Command));
return Subst;
}
"$((" {
BEGIN(push(Arith));
return Subst;
}
"`" {
BEGIN(push(Backtick));
return Subst;
}
}
<Param>"}" |
<Command>")" |
<Arith>"))" |
<Backtick>"`" {
BEGIN(pop());
return Subst;
}
"\n" {
first = true;
return Normal;
}
[&();|]|"&&"|";;"|"||" {
first = true;
return Operator;
}
[0-9]?([<>]"&"?|">|"|">>"|"<>") {
return Operator;
}
{reserved} {
if (first) {
first = false;
return Keyword;
}
return Normal;
}
{word}/[[:blank:]]*"()" { return Ident; }
[0-9]?("<<"|"<<-") {
BEGIN(push(HereDocDel));
return Operator;
}
<HereDocDel>{
[[:blank:]]+ { return Normal; }
{word} {
delimiter = strdup(yytext);
assert(delimiter);
BEGIN(pop(), push(HereDoc));
return Ident;
}
"'"{word}"'" {
delimiter = strndup(&yytext[1], strlen(yytext)-2);
assert(delimiter);
BEGIN(pop(), push(HereDocLit));
return Ident;
}
}
<HereDoc,HereDocLit>{
^"\t"*{word} {
if (strcmp(&yytext[strspn(yytext, "\t")], delimiter)) REJECT;
free(delimiter);
BEGIN(pop());
return Ident;
}
}
<HereDoc>{
[^$`\n]+ { return String; }
.|\n { return String; }
}
<HereDocLit>{
.*\n { return String; }
}
"'"[^'']*"'" { return String; }
"\""/[^$`\\] {
BEGIN(push(DQuote));
yymore();
}
"\"" {
BEGIN(push(DQuote));
return String;
}
<DQuote>{
[^\\$`""]*"\"" {
BEGIN(pop());
return String;
}
"\\"[$`""\\\n] { return Escape; }
[^\\$`""]+|. { return String; }
}
<INITIAL,Command,Backtick,Arith>"#".* { return Comment; }
{word} {
first = false;
return Normal;
}
.|\n { return Normal; }
%{
(void)yyunput;
(void)input;
%}
%%
const struct Lexer LexSh = { yylex, &yyin, &yytext };
|